таблица значений 1С

Таблица значений 1С – 3 часть. Метаданные. Перебор колонок таблицы значений

В этой статье я расскажу как работать с таблицей значений "неизвестной" структуры, как перебирать колонки таблицы значений, как извлекать данные из колонок и строк, не используя названия колонок. (Эта статья относится к циклу статей 1С с нуля; программирование 1с с нуля; таблица значений 1с)

Две предыдущие статьи:

Таблица значений 1С – 1 часть. Основы. Создание таблицы.
Таблица значений 1С – 2 часть. Основы. Обращение к данным, перебор строк таблицы значений

Для объяснения материала и для того, чтобы можно было запустить наши примеры программного кода "в живую", нам необходимая некая тестовая таблица значений 1С. Часть наших примеров будет извлекать данные из таблицы значений, поэтому мы сделаем таблицу с тремя колонками "Фамилия", "Имя", "Отчество" и внесем в нее небольшое количество данных - аж целых 3 строки :)

Итак, создадим тестовую таблицу значений 1С и заполним ее:

  МояТЗ = Новый ТаблицаЗначений;           // создаем новую таблицу значений, хранящуюся в переменной "МояТЗ"
  МояТЗ.Колонки.Добавить("Фамилия");      // создаем колонку "Фамилия"
  МояТЗ.Колонки.Добавить("Имя");            // создаем колонку "Имя"
  МояТЗ.Колонки.Добавить("Отчество");     // создаем колонку "Отчество"  
  // добавляем первую строку в нашу таблицу значений
  НоваяСтрока = МояТЗ.Добавить();  
  НоваяСтрока.Фамилия    = "Чапаев";
  НоваяСтрока.Имя          =    "Василий";
  НоваяСтрока.Отчество  = "Иванович";
  // добавляем вторую строку
  НоваяСтрока = МояТЗ.Добавить();  
  НоваяСтрока.Фамилия    = "Дзержинский";
  НоваяСтрока.Имя          =    "Феликс";
  НоваяСтрока.Отчество  = "Эдмундович";
  // добавляем третью строку
  НоваяСтрока = МояТЗ.Добавить();  
  НоваяСтрока.Фамилия    = "Котовский";
  НоваяСтрока.Имя          =    "Григорий";
  НоваяСтрока.Отчество  = "Иванович";

Наша тестовая таблица состоит из трех колонок: Имя, Фамилия, Отчество; и имеет три заполненных строки с фамилиями героев Гражданской войны.

Номер строкиФамилияИмяОтчество
0ЧапаевВасилийИванович
1ДзержинскийФеликсЭдмундович
2КотовскийГригорийИванович

Первый образец кода - перебор колонок таблицы значений 1С как коллекции.

  // выводим названия всех колонок ТЗ
  Для Каждого Колонка Из МояТЗ.Колонки Цикл
    Сообщить("Имя колонки: " + Колонка.Имя);
  КонецЦикла;

Наш цикл выведет в окно сообщений 1С все имена колонок:

Имя колонки: Фамилия
Имя колонки: Имя
Имя колонки: Отчество

Мы видим, что для перебора колонок применяется специальный цикл перебора коллекции, похожий на цикл перебора строк (в прошлой статье). МояТЗ.Колонки - это коллекция колонок таблицы значений 1С "МояТЗ". Коллекция содержит в себе объекты типа "КолонкаТаблицыЗначений" Каждый объект этого типа и является колонкой таблицы значений, и содержит свойства и методы. Обращаясь к этим свойствам и методам мы получаем нужные сведения об одной колонке или производим какие-то другие действия с ней.

Например, обращаясь к свойству "Имя" (Колонка.Имя) мы получаем имя текущей колонки.

Хочу обратить ваше внимание на заголовок цикла: "Для Каждого Колонка Из МояТЗ.Колонки Цикл" Переменная с именем "Колонка" придумана нами. Необязательно использовать такое же имя. Можно назвать эту переменную как угодно, например "МояТекущаяКолонка" Тогда пример выше будет выглядеть таким образом:

  // выводим названия всех колонок ТЗ
  Для Каждого МояТекущаяКолонка Из МояТЗ.Колонки Цикл
    Сообщить("Имя колонки: " + МояТекущаяКолонка.Имя);
  КонецЦикла;

Когда исполняющая подсистема 1С встречает цикл такого вида, при каждом проходе цикла она присваивает переменной с указанным именем один элемент из нашей коллекции, в данном случае - один элемент коллекции колонок таблицы значений МояТЗ.Колонки А далее мы обращаемся к переменной, которая содержит в себе текущую колонку, и используем свойство "Имя".

Предлагаю рядом с именем колонки вывести еще и номер каждой колонки в коллекции колонок:

  // выводим номер и названия всех колонок таблицы значений
  Для Каждого Колонка Из МояТЗ.Колонки Цикл
    НомерКолонки = МояТЗ.Колонки.Индекс(Колонка);  // получаем номер колонки
    ИмяКолонки   = Колонка.Имя;                    // получаем имя колонки
    Сообщить("Номер колонки:" + НомерКолонки + " Имя колонки: " + ИмяКолонки);
  КонецЦикла;

В окно сообщений 1С будет выведен текст:

Номер колонки:0 Имя колонки: Фамилия
Номер колонки:1 Имя колонки: Имя
Номер колонки:2 Имя колонки: Отчество

Обратим внимание на то, что колонки в таблице значений 1С нумеруются начиная с нуля, так же, как и строки таблицы значений.

Количество колонок в таблице значений 1С

Чтобы узнать количество колонок в таблице значений, мы используем метод "Количество()" у коллекции колонок.

   КоличествоКолонок = МояТЗ.Колонки.Количество();
  Сообщить(КоличествоКолонок);

На экране будет выведена цифра "3". Действительно, в нашей таблице три колонки: "Фамилия", "Имя", "Отчество"

Получение объекта- колонки по ее номеру (индексу) и перебор колонок при помощи индекса колонок

Сделаем цикл перебора всех колонок таблицы значений при помощи индексов колонок (номеров). Помним, что нумерация колонок начинается с нуля. Поэтому счетчик цикла "Сч" мы должны наращивать от нуля до числа, равного количеству колонок минус один.

  Для Сч = 0 По МояТЗ.Колонки.Количество() - 1 Цикл
    ТекущаяКолонка = МояТЗ.Колонки[Сч];
    Сообщить(ТекущаяКолонка.Имя);
  КонецЦикла;  

На экране мы получим следующее

Фамилия
Имя
Отчество

Думаю, что этот пример был понятен. Мы обратились к методу Количество() коллекции колонок "МояТЗ.Колонки.Количество()", получили количество колонок, и запустили цикл со счетчиком от нуля до количество колонок минус один. Внутри цикла мы получаем каждую колонку из коллекции колонок и присваиваем текущий объект-колонку в переменную ТекущаяКолонка Далее, у переменной ТекущаяКолонка мы обращаемся к свойству Имя и выводим значение этого свойства на экран: Сообщить(ТекущаяКолонка.Имя);

Важно никогда не путать свойство объекта и метод объекта.

Свойство - это некая статическая величина и обращение к нему пишется без скобок, например ТекущаяКолонка.Имя. А метод - это по сути, процедура или функция объекта, а вызовы процедур и функций всегда пишутся со скобками (даже если нет входных параметров). Например: МояТЗ.Колонки.Количество()

Если мы обратимся к методу, забыв написать скобки - интерпретатор 1С выдаст нам сообщение об ошибке и не запустит код на выполнение. Так как интерпретатор будет считать, что мы обращаемся не к методу, а к свойству - потому что нет скобок. А свойства с таким именем найти не сможет (потому что с таким именем имеется только метод) - о чем и будет сказано в сообщении об ошибке.

Вот что напишет интерпретатор, если я забуду поставит скобки в вызове метода таким неправильным способом МояТЗ.Колонки.Количество (без скобок после "Количество()"):

Поле объекта не обнаружено (Количество)

В данном случае "поле" и "свойство" следует понимать как синонимы, или неточность терминологии разработчиков 1С. Они используют оба этих слова для обозначения одного и того же понятия. Хотя в других языках программирования эти термины могут означать разные понятия.

Получение данных из таблицы значений 1С при помощи номеров колонок

Предлагаю вам, для начала, простой пример получения данных из первой строки нашей таблицы. Обратите внимание, что мы используем заранее заполненную таблицу из начала статьи. Мы точно знаем, что в таблице есть первая строка, и есть хотя бы одна колонка. Если мы применим этот пример к незаполненной таблице, то произойдет ошибка. Итак:

  ПерваяСтрока = МояТЗ[0];                 // получаем первую строку (нумерация с нуля)
  ЗначениеПервойКолонки = ПерваяСтрока[0]; // получаем значение первой колонки (нумерация колонок тоже с нуля)
  Сообщить(ЗначениеПервойКолонки);         // выводим на экран значение первого столбца в первой строке таблицы

На экран будет выведено:

Чапаев

Сначала мы получили объект-строку таблицы значений, обратившись к таблице значений при помощи оператора [...]. (если забыли, как это делается, можно посмотреть предыдущие статьи) Внутрь оператора мы передали аргумент "0". Это индекс первой строки таблицы значений. ПерваяСтрока = МояТЗ[0];

Далее, к объекту-строке мы тоже имеем право обратиться при помощи оператора [...]. Внутрь этого операторы мы передали номер столбца таблицы значений, в данном случае тоже "0". И, таким образом, мы получили значение столбца с номером "0" для текущей строки таблицы под номером "0". Это значение мы вывели на экран и оно представляет собой строку "Чапаев".

Немного усложним наш пример:

  ПерваяСтрока = МояТЗ[0];           // получаем первую строку (нумерация с нуля)
  Сообщить(ПерваяСтрока[0]);         // выводим на экран значение первого столбца в первой строке таблицы
  Сообщить(ПерваяСтрока[1]);         // выводим на экран значение второго столбца в первой строке таблицы
  Сообщить(ПерваяСтрока[2]);         // выводим на экран значение третьего столбца в первой строке таблицы  

Теперь мы вывели на экран значения из всех трех столбцов первой строки нашей таблицы значений:

Чапаев
Василий
Иванович

Теперь я еще модифицирую этот пример, чтобы нам обойтись без переменной "ПерваяСтрока"

  Сообщить(МояТЗ[0][0]);         // выводим на экран значение первого столбца в первой строке таблицы
  Сообщить(МояТЗ[0][1]);         // выводим на экран значение второго столбца в первой строке таблицы
  Сообщить(МояТЗ[0][2]);         // выводим на экран значение третьего столбца в первой строке таблицы  

На экране будет тоже самое

Чапаев
Василий
Иванович

Мы увидели в примере выше, что для обращения к значению, находящемуся в конкретной строке и конкретном столбце таблицы значений мы можем использовать последовательный вызов двух операторов [...] в такой форме: ТаблицаЗначений[ИндексСтроки][ИндексКолонки]

Значит, мы готовы к тому, чтобы создать цикл перебора и получить данные всех строк и всех столбцов при помощи индексов строк и столбцов:

  Для СчетчикСтрок = 0 По МояТЗ.Количество() - 1 Цикл                 // цикл перебора строк
    Для СчетчикКолонок = 0 По МояТЗ.Колонки.Количество() - 1 Цикл // вложенный цикл перебора столбцов
      // получаем значение ячейки (из текущей строки и текущей колонки)
      ЗначениеЯчейки = МояТЗ[СчетчикСтрок][СчетчикКолонок];
      // выводим на экран номер строки, номер колонки и значение ячейки
      Сообщить("Строка №" + СчетчикСтрок + " столбец №" + СчетчикКолонок + " = " + ЗначениеЯчейки);
    КонецЦикла;
  КонецЦикла;  

На экран будет выведено следующее:

Строка №0 столбец №0 = Чапаев
Строка №0 столбец №1 = Василий
Строка №0 столбец №2 = Иванович
Строка №1 столбец №0 = Дзержинский
Строка №1 столбец №1 = Феликс
Строка №1 столбец №2 = Эдмундович
Строка №2 столбец №0 = Котовский
Строка №2 столбец №1 = Григорий
Строка №2 столбец №2 = Иванович

При помощи двух циклов, один из которых вложен в другой, мы вывели на экран значения всех колонок из всех строк таблицы значений 1С. При этом мы не использовали имена колонок, а обращались к колонкам и строкам по их индексам. Для большего понимания обратите внимание на комментарии внутри примера.

Предлагаю, в заключение, немного изменить наш пример, чтобы он вместо номеров колонок выводил на экран их названия. И дополнительно сделаю более презентабельное оформление выдачи содержимого на экран.

  Для СчетчикСтрок = 0 По МояТЗ.Количество() - 1 Цикл                 // цикл перебора строк
    Сообщить(" ======= Строка № " + СчетчикСтрок + " =======");
    Сообщить(" "); // перевод строки (вставка пустой строки)
    Для СчетчикКолонок = 0 По МояТЗ.Колонки.Количество() - 1 Цикл // вложенный цикл перебора столбцов
      // получаем значение ячейки (из текущей строки и текущей колонки)
      ЗначениеЯчейки = МояТЗ[СчетчикСтрок][СчетчикКолонок];
      // получаем имя колонки
      ИмяКолонки = МояТЗ.Колонки[СчетчикКолонок].Имя;      
      // выводим на экран имя колонки и значение ячейки
      Сообщить(ИмяКолонки + ": " + ЗначениеЯчейки);
    КонецЦикла;
    Сообщить(" "); // перевод строки (вставка пустой строки)
  КонецЦикла;  

Сейчас, на нашем экране информация стала выглядеть более представительно:

 ======= Строка № 0 =======
 
Фамилия: Чапаев
Имя: Василий
Отчество: Иванович
 
 ======= Строка № 1 =======
 
Фамилия: Дзержинский
Имя: Феликс
Отчество: Эдмундович
 
 ======= Строка № 2 =======
 
Фамилия: Котовский
Имя: Григорий
Отчество: Иванович
 

Да, чуть не забыл. При использовании подряд двух операторов [...][...], мы можем вместо индекса колонки передавать имя этой колонки: ТаблицаЗначений[ИндексСтроки][ИмяКолонки]

  Для СчетчикСтрок = 0 По МояТЗ.Количество() - 1 Цикл                 // цикл перебора строк
    Сообщить(" ======= Строка № " + СчетчикСтрок + " =======");
    Сообщить(" "); // перевод строки (вставка пустой строки)
    Для СчетчикКолонок = 0 По МояТЗ.Колонки.Количество() - 1 Цикл // вложенный цикл перебора столбцов
      ИмяКолонки = МояТЗ.Колонки[СчетчикКолонок].Имя;   // получаем имя колонки   
      ЗначениеЯчейки = МояТЗ[СчетчикСтрок][ИмяКолонки]; // <---- получаем значение ячейки ПО ИМЕНИ колонки и номеру строки
      Сообщить(ИмяКолонки + ": " + ЗначениеЯчейки);     // выводим на экран имя колонки и значение ячейки
    КонецЦикла;
    Сообщить(" "); // перевод строки (вставка пустой строки)
  КонецЦикла;  

Обратите внимание на строку, отмеченную стрелочкой "<----". В этой строке мы вместо индекса текущей колонки передаем имя текущей колонки в аргумент в квадратных скобках [...] Результат будет тот же самый.

А сейчас, последнее в этой статье.

ПРАВИЛЬНОЕ получение всех данных таблицы значений 1С, при помощи циклов перебора коллекции строк и коллекции колонок

  Для Каждого ТекущаяСтрока Из МояТЗ Цикл                // цикл перебора коллекции строк
    Сообщить(" ======= Строка № " + МояТЗ.Индекс(ТекущаяСтрока) + " =======");
    Сообщить(" "); 
    Для Каждого ТекущаяКолонка Из МояТЗ.Колонки Цикл     // вложенный цикл перебора коллекции столбцов
      ИмяКолонки = ТекущаяКолонка.Имя;               // получаем имя колонки   
      ЗначениеЯчейки = ТекущаяСтрока[ИмяКолонки];    // получаем значение ячейки ПО ИМЕНИ колонки
      Сообщить(ИмяКолонки + ": " + ЗначениеЯчейки);  // выводим на экран имя колонки и значение ячейки
    КонецЦикла;
    Сообщить(" "); 
  КонецЦикла;  

В примере было использовано два цикла. Цикл перебора коллекции колонок вложен внутрь цикла перебора строк. Если вы разбирались с примерами выше, и читали предыдущие статьи, то у вас не будет затруднений в понимании работы этого примера.

Напоследок, я максимально сокращу количество строк кода нашего последнего примера, исключив использование промежуточных переменных. Мы получим образец "промышленного кода", который используется в реальных задачах.

Это следует делать только тогда, когда вы хорошо понимаете то, что делаете. Если же код очень сложен, то допустимо оставлять промежуточные переменные, чтобы облегчить понимание собственного кода впоследствии. Так же любой код необходимо хотя бы минимально комментировать, чтобы спустя какое-то время было легче разобраться с текстами программы.

  Для Каждого ТекущаяСтрока Из МояТЗ Цикл                // перебор строк
    Сообщить(" ======= Строка № " + МояТЗ.Индекс(ТекущаяСтрока) + " =======" + Символы.ПС);
    
    Для Каждого ТекущаяКолонка Из МояТЗ.Колонки Цикл     // перебор столбцов
      Сообщить(ТекущаяКолонка.Имя + ": " + ТекущаяСтрока[ТекущаяКолонка.Имя]);    
    КонецЦикла;
    
    Сообщить(" "); 
  КонецЦикла;  

Вывод на экран не изменился, остался такой же, как в прошлом примере:

 ======= Строка № 0 =======

Фамилия: Чапаев
Имя: Василий
Отчество: Иванович
 
 ======= Строка № 1 =======

Фамилия: Дзержинский
Имя: Феликс
Отчество: Эдмундович
 
 ======= Строка № 2 =======

Фамилия: Котовский
Имя: Григорий
Отчество: Иванович

С уважением, Дегтярев Роман
Сайт fast-soft.ru - cкачать бесплатные программы на русском, научиться пользоваться компьютером, научиться программировать

Как научиться программировать в 1С с нуля

Как работать программистом 1С и получать до 150 000 рублей в месяц?

ЗАПИШИСЬ НА БЕСПЛАТНЫЙ 2-НЕДЕЛЬНЫЙ МИНИ-КУРС

ПРОГРАММИРОВАНИЕ в 1С

ДЛЯ НОВИЧКОВ !

Курс придет на электронную почту. Стань программистом, выполняя пошаговые задания.

Для участия нужен только компьютер и интернет

Бесплатный доступ на курс:



Комментарии для тех, кто VKontakte


2 комментария: Таблица значений 1С – 3 часть. Метаданные. Перебор колонок таблицы значений 1С

  • chidaystory говорит:

    Спасибо, доступно и понятно.

  • Вова говорит:

    Хорошие статейки, спасибо помогли на первых порах. Хотел маленькое замечание по сайту сделать. В главной менюшке(в шапке или под ней), когда выпадает список, подсказка закрывает первую строку списка. :!: Не приятная штука :oops:

Оставить комментарий

Ваш email не будет опубликован. Обязательные поля отмечены *

Вы можете использовать это HTMLтеги и атрибуты: <a href="" title=""> <abbr title=""> <acronym title=""> <b> <blockquote cite=""> <cite> <code> <del datetime=""> <em> <i> <q cite=""> <strike> <strong>

Интернет-курс "Программирование в 1С с нуля"

Учись программировать и зарабатывать до
150 000 руб. в месяц! ТОЛЬКО СЕГОДНЯ - БЕСПЛАТНЫЙ ДОСТУП К КУРСУ!

Присоединяйся, тут все свои!